nomsu/tools/parse.nom

#!/usr/bin/env nomsu -V3.6.5.6
#
    Tool to print out a parse tree of files in an easy-to-read format. Usage:
        nomsu tools/parse.nom file1 file2 directory1 ...        

use "lib/os.nom"

action [print tree %t at indent %indent]:
    if %t.type is:
        "Action":
            say "\(%indent)Action (\(%t.stub)):"
            if %t.target:
                say "\(%indent)  Target:"
                print tree %t.target at indent "\%indent    "
            for %arg in %t:
                if (%arg is syntax tree):
                    print tree %arg at indent "\%indent  "
        
        "Number":
            say "\%indent\(%t.1)"
        "Var":
            say "\(%indent)%\(%t.1)"
        else:
            say "\%indent\(%t.type):"
            for %arg in %t:
                if:
                    (%arg is syntax tree):
                        print tree %arg at indent "\%indent  "
                    else:
                        say "\%indent  \(quote %arg)"

for %path in (=lua "arg"):
    for file %filename in %path:
        unless (%filename matches "%.nom$"): do next %filename
        print tree (parse (read file %filename) from %filename) at indent ""