Switching hashes to use base64 instead of hex.

lib/base64.nom

@@ -0,0 +1,54 @@
+#!/usr/bin/env nomsu -V2.5.5.4
+#
+    This file defines actions for encoding/decoding base 64, as specified in:
+    https://tools.ietf.org/html/rfc4648
+
+%b64_str = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/"
+%reverse_b64 = (%b64_str.%i = (%i - 1) for %i in 1 to (length of %b64_str))
+%reverse_b64."=" = 0
+test:
+    %cases = ["", "Zg==", "Zm8=", "Zm9v", "Zm9vYg==", "Zm9vYmE=", "Zm9vYmFy"]
+    for %len = %encoded in %cases:
+        %plain = "foobar".[1, %len - 1]
+        assume ((base64 %plain) == %encoded) or barf ".."
+            \(quote %plain) base64 encoded to \(quote (base64 %plain)) \
+            ..instead of \(quote %encoded)
+        assume ((base64 decode %encoded) == %plain) or barf ".."
+            \(quote %encoded) base64 decoded to \(quote (base64 decode %encoded)) \
+            ..instead of \(quote %plain)
+
+action [base64 %str, base64 encode %str, %str base64]:
+    %chars = []
+    for %i in 1 to (length of %str) via 3:
+        %bytes = [=lua "\%str:byte(\%i, \(%i + 2))"]
+        add %b64_str.(((%bytes.1 & 252) >> 2) + 1) to %chars
+        if (length of %bytes) is:
+            3:
+                add %b64_str.(((%bytes.1 & 3) << 4) + ((%bytes.2 & 240) >> 4) + 1) to %chars
+                add %b64_str.(((%bytes.2 & 15) << 2) + ((%bytes.3 & 192) >> 6) + 1) to %chars
+                add %b64_str.((%bytes.3 & 63) + 1) to %chars
+            
+            2:
+                add %b64_str.(((%bytes.1 & 3) << 4) + ((%bytes.2 & 240) >> 4) + 1) to %chars
+                add %b64_str.(((%bytes.2 & 15) << 2) + 1) to %chars
+                add "=" to %chars
+            
+            1:
+                add %b64_str.(((%bytes.1 & 3) << 4) + 1) to %chars
+                add "=" to %chars
+                add "=" to %chars
+    
+    return (%chars joined)
+
+action [chr %] (=lua "string.char(\%)")
+action [decode base64 %str, %str base64 decoded, base64 decode %str]:
+    %chars = []
+    for %i in 1 to (length of %str) via 4:
+        %indices = (%reverse_b64.(%str.%) for % in %i to (%i + 3))
+        add (chr ((%indices.1 << 2) + ((%indices.2 & 48) >> 4))) to %chars
+        if (%str.(%i+2) == "="): stop
+        add (chr (((%indices.2 & 15) << 4) + ((%indices.3 & 60) >> 2))) to %chars
+        if (%str.(%i+3) == "="): stop
+        add (chr (((%indices.3 & 3) << 6) + %indices.4)) to %chars
+    
+    return (%chars joined)

lib/file_hash.nom

@@ -2,25 +2,23 @@
 #
     This file defines some actions for hashing files and looking up files by hash.
 
-action [file with hash %hash]:
-    lua> ".."
-        local Hash = require("openssl.digest")
-        for filename in io.popen('find -L . -not -path "*/\\\\.*" -type f -name "*.nom"'):lines() do
-            local file = io.open(filename)
-            local contents = file:read("*a")
-            file:close()
-            local hash = Hash.new("sha1"):final(contents)
-            local hex = hash:gsub('.', function(c) return string.format('%02x', string.byte(c)) end)
-            if hex == \%hash then
-                return filename
-            end
-        end
+use "lib/os.nom"
+use "lib/base64.nom"
+
+%hashlib = (=lua "require('openssl.digest')")
+
+test:
+    assume ((hash "hello world") == "Kq5sNclPz7QV2+lfQIuc6R7oRu0=")
 
 action [hash %, sha1 %]:
-    %hashlib = (=lua "require('openssl.digest')")
     %hash = (=lua "\%hashlib.new('sha1'):final(\%)")
-    return (..)
-        =lua ".."
-            \%hash:gsub('.', function(c) return string.format('%02x', string.byte(c)) end)
+    return (base64 %hash)
 
-parse [hash of file %filename] as (sha1 (=lua "io.open(\%filename):read('*a')"))
+action [file with hash %hash]:
+    for file %filename in ".":
+        %contents = (read file %filename)
+        %file_hash = (hash %contents)
+        if (%file_hash == %hash):
+            return %filename
+
+parse [hash of file %filename] as (sha1 (read file %filename))