#!/usr/bin/env nomsu -V5.12.12.8
#
    Auto-format Nomsu code. Usage:
        nomsu -t autoformat [-i] file1 file2...

    If the "-i" flag is used, the file will be edited in-place.
    If no files are passed in, this will read from stdin.
    
use "lib/os.nom"

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

$filenames = $(COMMAND LINE ARGS).extras
if ((#$filenames) == 0):
    say "Warning: reading from stdin (ctrl-d to abort). To avoid this message, use nomsu -t autoformat -"
    $filenames = ["stdin"]

for $filename in $filenames:
    $file = (read file $filename)
    unless $file:
        barf "File does not exist: \$filename"
    $leading_indent = ($file|matching "[\n]*([ ]*)")
    $code = (NomsuCode from ($Source $filename 1 (size of $file)) $file)
    $tree = ($code parsed)
    $formatted = "
        \$leading_indent\((($tree as nomsu)|text)|with "\n" -> "\n\$leading_indent")"
    
    if $(COMMAND LINE ARGS)."-i":
        write $formatted to file $filename
    ..else:
        say $formatted inline