#!/usr/bin/env nomsu -V4.8.8.6
#
    Tool to automatically update code from old versions of Nomsu. Usage:
        nomsu tools/upgrade.nom [-i] file1 file2 directory1 ...
    If "-i" is the first argument, upgrades will be performed in-place. Otherwise, the
    upgraded code will be printed.

use "compatibility"
use "lib/os.nom"

%args = (command line args)
%inplace = (no)
if (%args.1 is "-i"):
    %inplace = (yes)
    %args::remove index 1

if (%args.1 is "-t"):
    use "lib/consolecolor.nom"
    %test = (yes)
    %args::remove index 1

for %path in %args:
    for file %filename in %path:
        unless (%filename::matches "%.nom$"): do next %filename
        %tree = (parse (read file %filename) from %filename)
        %uptree = (%tree upgraded)
        %text = "\
            ..#!/usr/bin/env nomsu -V\(Nomsu version)
            \(%uptree as nomsu)"
        
        if:
            %inplace:
                say "Upgraded \%filename"
                write %text to file %filename
            
            %test:
                if (%uptree == %tree):
                    say (dim "\%filename will not be changed")
                ..else:
                    say (bright "\%filename will be changed")
            
            else: say %text