" Language:    Nomsu
" Maintainer:  Bruce Hill <bruce@bruce-hill.com>
" License:     WTFPL

" Bail if our syntax is already loaded.
if exists('b:current_syntax') && b:current_syntax == 'nomsu'
  finish
endif

" Highlight long strings.
syn sync minlines=100
"highlight String ctermbg=DarkBlue ctermfg=Black

" Regular strings
"
syn region nomsuInterp matchgroup=nomsuInterpDelim start=/\\/ end=/\\/ contained
\                       contains=@nomsuAll
hi def link nomsuInterpDelim PreProc
syn region nomsuOneLineComment start=/#/ end=/$/
hi def link nomsuOneLineComment Comment
syn region nomsuComment start=/#\.\.[^\n]*$\n\(\s*\n\)*\z(\s\+\)\S/ skip=/^\%(\z1\S\|^\s*$\)/ end=/^\z1\@!.*/me=s-1
hi def link nomsuComment Comment

syn region nomsuString1 start=/"\(\(\.\."\)\@!\|\.\."\s*|.*$\)/ skip=/\\\\\|\\"/ end=/"/
hi def link nomsuString1 String

syn region nomsuStringLine start=/"\.\."/ end=/$/
\           contains=nomsuInterp,nomsuStringLineStart,nomsuStringTrailingSpace,nomsuOneLineComment,nomsuComment
hi def link nomsuStringLine String

syn match nomsuStringLineStart /\(^[ \t]*\|"\.\."\s*\)\@<=|/ contained
hi def link nomsuStringLineStart Delimiter
syn match nomsuStringTrailingSpace /[ \t]*$/ contained
hi nomsuStringTrailingSpace ctermbg=Magenta


syn region nomsuLongString start=/"\.\."[^\n]*$\n\(\s*\n\)*\z(\s\+\)\S/ skip=/^\%(\z1\S\|^\s*$\)/ end=/^\z1\@!.*/me=s-1
\           contains=nomsuInterp,nomsuStringLineStart,nomsuStringTrailingSpace,nomsuOneLineComment,nomsuComment
hi def link nomsuLongString String

syn match nomsuVar /\v\%[a-zA-Z0-9_'+*/^&$@#-]*/
hi def link nomsuVar Identifier

syn match nomsuNumber /\v([a-zA-Z])@<!\d+\.\d+/
syn match nomsuNumber /\v([a-zA-Z])@<!\d+/
hi def link nomsuNumber Number

syn match nomsuIndentor /\[\.\.\]/
syn match nomsuIndentor /(\.\.)/
syn match nomsuIndentor /\.\.\s*$/
syn match nomsuIndentor /^\s*\.\./
hi def link nomsuIndentor Special

syn match nomsuIndentor /\.\./
hi def link nomsuIndentor Delimiter

syn match nomsuComma /,/
hi def link nomsuComma Delimiter

syn match nomsuThunk /:/
hi def link nomsuThunk Structure

syn match nomsuToken /\v(\%)@<!\%[a-zA-Z_'+*/^&$@#-][a-zA-Z0-9_'+*/^&$@#-]*/
hi def link nomsuToken Function

syn cluster nomsuAll contains=nomsuString1,nomsuLongString,nomsuComment,
\                             nomsuVar,nomsuNumber,nomsuComma,nomsuThunk,nomsuIndentor,nomsuToken

if !exists('b:current_syntax')
  let b:current_syntax = 'nomsu'
endif