Initial commit

README.md

@@ -0,0 +1 @@
+This is a vim plugin for Parsing Expression Grammars, using the LPEG syntax.

ftdetect/peg.vim

@@ -0,0 +1,5 @@
+" Language:    PEG
+" Maintainer:  Bruce Hill <bruce@bruce-hill.com>
+" License:     WTFPL
+
+autocmd BufNewFile,BufRead *.peg set filetype=peg

ftplugin/peg.vim

@@ -0,0 +1,13 @@
+" Language:    PEG
+" Maintainer:  Bruce Hill <bruce@bruce-hill.com>
+" License:     WTFPL
+
+if exists("b:did_ftplugin")
+  finish
+endif
+let b:did_ftplugin = 1
+
+setlocal formatoptions-=t
+setlocal cpoptions+=M
+
+let b:undo_ftplugin = "setlocal formatoptions< cpoptions<"

indent/peg.vim

@@ -0,0 +1,39 @@
+" Language:    PEG
+" Maintainer:  Bruce Hill <bruce@bruce-hill.com>
+" License:     WTFPL
+
+if exists("b:did_indent")
+  finish
+endif
+
+let b:did_indent = 1
+
+setlocal autoindent
+setlocal indentexpr=GetPEGIndent()
+setlocal indentkeys+=-:
+
+" Only define the function once.
+if exists("*GetPEGIndent")
+  finish
+endif
+
+function! GetPEGIndent()
+  let line = getline(v:lnum)
+  let current_ind = indent(v:lnum)
+  let previousNum = prevnonblank(v:lnum - 1)
+  let previous = getline(previousNum)
+  let ind = indent(previousNum)
+
+  if previous =~ '<-\s*\($\|--\)' || previous =~ ':\s*\($\|--\)'
+    let ind = &tabstop
+  endif
+
+  if line =~ '^\s*\w\+\s*<-\|^\s*\w\+\s*(\s*\w+\s*)\s*:'
+    let ind = 0
+  endif
+
+  if ind == indent(previousNum)
+      return current_ind
+  endif
+  return ind
+endfunction

syntax/peg.vim

@@ -0,0 +1,74 @@
+" Language:    PEG
+" Maintainer:  Bruce Hill <bruce@bruce-hill.com>
+" License:     WTFPL
+
+" Bail if our syntax is already loaded.
+if exists('b:current_syntax') && b:current_syntax == 'peg'
+  finish
+endif
+
+syn region PEGComment start=/--/ end=/$/
+hi def link PEGComment Comment
+hi PEGComment ctermfg=DarkBlue
+
+syn region PEGString start=/\z(["']\)/ end=/\z1/
+hi def link PEGString String
+
+syn region PEGGroup matchgroup=PEGGroupBrackets start=/\[/ end=/]/ contains=PEGExternal,PEGNegateGroup,PEGGroupRange
+hi PEGGroup ctermfg=Magenta
+hi PEGGroupBrackets ctermfg=LightMagenta
+
+syn match PEGNegateGroup ;\[\@<=\^; contained
+hi PEGNegateGroup ctermfg=Gray
+
+syn match PEGGroupRange ;\-]\@!; contained
+hi PEGGroupRange ctermfg=Gray
+
+syn match PEGOperator ;[+*?&!]\|->\|\^[+-]\?\d\+; contains=PEGNumber
+hi PEGOperator ctermfg=White
+
+syn match PEGSlash ;/;
+hi PEGSlash ctermfg=DarkGray
+
+syn match PEGNumber /[+-]\?\d\+/ contained
+hi PEGNumber ctermfg=Red
+
+syn match PEGDot /\./
+hi PEGDot ctermfg=LightYellow cterm=bold
+
+syn region PEGTable start=/{|/ end=/|}/ contains=@PEGAll
+hi PEGTable ctermfg=Green
+
+syn region PEGParens start=/(/ end=/)/ contains=@PEGAll
+hi PEGParens ctermfg=Yellow
+
+syn region PEGNamedCapture matchgroup=PEGNamedCapture start=/{:\w\+:/rs=e end=/:}/ contains=@PEGAll
+hi PEGNamedCapture ctermfg=LightBlue
+
+syn region PEGSub start=/{\~/ end=/\~}/ contains=@PEGAll
+hi PEGSub ctermfg=DarkRed
+
+syn region PEGCapture start=/{[:|~]\@!/ end=/[:|~]\@<!}/ contains=@PEGAll
+hi PEGCapture ctermfg=LightBlue
+
+syn match PEGName /\w\+/
+hi PEGName ctermfg=none
+
+syn match PEGExternal /%\w\+/
+hi PEGExternal ctermfg=Cyan
+
+syn match PEGBackref /=\w\+/
+hi PEGBackref ctermfg=LightBlue
+
+syn match PEGDef /\w\+\(\s*(\s*\w\+\s*)\)\?\s*<-/ contains=PEGDefName
+hi PEGDef ctermfg=White cterm=bold
+
+syn match PEGDefName /(\s*\w\+\s*)/ contained
+hi PEGDefName ctermfg=Gray
+
+syn cluster PEGAll contains=PEGComment,PEGString,PEGGroup,PEGOperator,PEGSlash,PEGTable,PEGParens,
+            \PEGNamedCapture,PEGCapture,PEGName,PEGExternal,PEGBackref,PEGDef,PEGDot
+
+if !exists('b:current_syntax')
+  let b:current_syntax = 'peg'
+endif