#!/usr/bin/env nomsu -V7.0.0

###
    This file defines upgrades from Nomsu <4.8.10 to 4.8.10 (renaming "action" -> "means")
use "compatibility/compatibility"

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

upgrade action "local action" to "4.8.10" via
    for ($tree $end_version):
        $spec = $tree.3
        $body = $tree.4
        if $spec.type is:
            "List":
                if (#$spec == 1):
                    return ("Action" tree with $spec.1 "means" $body)
                ..else:
                    return ("Action" tree with $spec "all" "mean" $body)
            
            else:
                return ("Action" tree with $spec "means" $body)

upgrade action "action" to "4.8.10" via
    for ($tree $end_version):
        $spec = $tree.2
        $body = $tree.3
        if $body:
            if $spec.type is:
                "List":
                    if (#$spec == 1):
                        return ("Action" tree with "externally" $spec.1 "means" $body)
                    ..else:
                        return ("Action" tree with "externally" $spec "all" "mean" $body)
                
                else:
                    return ("Action" tree with "externally" $spec "means" $body)
        ..else:
            return ("Action" tree with $spec "'" "s" "meaning")

upgrade action "compile 1 to" to "4.8.10" via
    for ($tree $end_version):
        $spec = $tree.2
        $body = $tree.4
        if $spec.type is:
            "List":
                if (#$spec == 1):
                    return ("Action" tree with $spec.1 "compiles" "to" $body)
                ..else:
                    return ("Action" tree with $spec "all" "compile" "to" $body)
            
            else:
                return ("Action" tree with $spec "compiles" "to" $body)

upgrade action "parse 1 as" to "4.8.10" via
    for ($tree $end_version):
        $spec = $tree.2
        $body = $tree.4
        if $spec.type is:
            "List":
                if (#$spec == 1):
                    return ("Action" tree with $spec.1 "parses" "as" $body)
                ..else:
                    return ("Action" tree with $spec "all" "parse" "as" $body)
            
            else:
                return ("Action" tree with $spec "parse" "as" $body)

upgrade action (compile as $) to "4.8.10" as (what $ compiles to)
upgrade action (remove action $) to "4.8.10" as (($'s meaning) = (nil))