1 # Structs
   2 
   3 In Tomo, you can define your own structs, which hold members with arbitrary
   4 types that can be accessed by fields:
   5 
   6 ```tomo
   7 struct Foo(name:Text, age:Int)
   8 ...
   9 my_foo := Foo("Bob", age=10)
  10 assert my_foo == Foo(name="Bob", age=10)
  11 assert my_foo.name == "Bob"
  12 ```
  13 
  14 Structs are value types and comparisons on them operate on the member values
  15 one after the other.
  16 
  17 ## Namespaces
  18 
  19 Structs can define their own methods that can be called with a `:` or different
  20 values that are stored on the type itself.
  21 
  22 ```tomo
  23 struct Foo(name:Text, age:Int)
  24     oldest := Foo("Methuselah", 969)
  25 
  26     func greet(f:Foo)
  27         say("Hi my name is $f.name and I am $f.age years old!")
  28 
  29     func get_older(f:@Foo)
  30         f.age += 1
  31 ...
  32 my_foo := @Foo("Alice", 28)
  33 my_foo.greet()
  34 my_foo.get_older()
  35 ```
  36 
  37 Method calls work when the first argument is the struct type or a pointer to
  38 the struct type.
  39 
  40 ## Secret Values
  41 
  42 If you want to prevent accidental leaking of sensitive information, you can
  43 create a struct with the `secret` flag turned on, which causes the struct to
  44 be converted to text without showing any of its contents:
  45 
  46 ```tomo
  47 struct Password(raw_password_text:Text; secret)
  48 struct User(username:Text, password:Password)
  49 ...
  50 user := User("Stanley", Password("Swordfish"))
  51 assert user == User("Stanley", Password("Swordfish"))
  52 assert "You are: $user" == 'You are: User(username="Stanley", password=Password(...))'
  53 ```
  54 
  55 Designing APIs so they take secrecy-protected structs instead of raw data
  56 values is a great way to prevent accidentally leaking sensitive information in
  57 your logs! Secrecy-protected values still work the same as any other struct,
  58 they just don't divulge their contents when converting to strings:
  59 
  60 ```tomo
  61 assert user.password == Password("Swordfish")
  62 ```
  63 
  64 You can also access the fields directly, but hopefully this extra amount of
  65 friction reduces the chances of accidentally divulging sensitive content:
  66 
  67 ```tomo
  68 assert user.password.raw_password_text == "Swordfish"
  69 ```