code / hill-noise

   1 #define TAU 6.283185307179586476925286766559005768394338798750211641949
   2 #define PHI 1.618033988749894848204586834365638117720309179805762862135
   3 #define LOG_PHI 0.481211825059603447497758913424368423135184334385660519660
   4 #define SQRT5 2.236067977499789696409173668731276235440618359611525724270
   5 #define MAX_RESOLUTION 64
   6 extern int resolution;
   7 extern float sigma;
   8 extern float amplitudes[MAX_RESOLUTION];
   9 extern vec3 offsets[MAX_RESOLUTION];
  10 extern float z;
  11 extern vec2 range_min, range_max;
  12 
  13 float cdf(float x) {
  14     return .5 + .5*sign(x)*sqrt(1.-exp(-4./TAU * x*x));
  15 }
  16 
  17 // https://www.graphics.rwth-aachen.de/media/papers/jgt.pdf
  18 float noise3d(vec3 pos) {
  19     // Find the biggest fibonacci number F_n such that F_n < RESOLUTION
  20     int n = int(log((float(resolution)-1.)*SQRT5 + .5)/LOG_PHI);
  21     int dec = int(.5 + pow(PHI,n)/SQRT5); // F_n, using closed form Fibonacci
  22     int inc = int(.5 + dec/PHI); // F_(n-1)
  23 
  24     float noise = 0.;
  25     for (int i=0, j=0; i<resolution; ++i) {
  26         if (j >= dec) {
  27             j -= dec;
  28         } else {
  29             j += inc;
  30             if (j >= resolution)
  31                 j -= dec;
  32         }
  33         // Convert golden ratio sequence into polar coordinate unit vector
  34         float phi = mod(float(i)*PHI,1.)*TAU;
  35         float theta = acos(mix(-1.,1.,mod(float(j)*PHI,1.)));
  36         // Make an orthonormal basis, where n1 is from polar phi/theta,
  37         // n2 is roated 90 degrees along phi, and n3 is the cross product of the two
  38         vec3 n1 = vec3(sin(phi)*cos(theta), sin(phi)*sin(theta), cos(phi));
  39         vec3 n2 = vec3(sin(phi+TAU/4.)*cos(theta), sin(phi+TAU/4.)*sin(theta), cos(phi+TAU/4.));
  40         vec3 n3 = cross(n1,n2);
  41         // Convert pos from x/y/z coordinates to n1/n2/n3 coordinates
  42         float u = dot(n1, pos);
  43         float v = dot(n2, pos);
  44         float w = dot(n3, pos);
  45         // Pull the amplitude from the shuffled array index ("j"), not "i",
  46         // otherwise neighboring unit vectors will have similar amplitudes!
  47         float a = amplitudes[j];
  48         //float a = pow(mod(float(i+1)*(PHI-1.), 1.), .3);
  49         // Noise is the average of cosine of distance along each axis, shifted by offsets and scaled by amplitude.
  50         noise += a*(cos(u/a + offsets[i].x) + cos(v/a + offsets[i].y) + cos(w/a + offsets[i].z))/3.;
  51     }
  52     return cdf(noise/sigma);
  53 }
  54 
  55 vec4 effect(vec4 color, Image texture, vec2 texture_coords, vec2 pixel_coords)
  56 {
  57     vec3 coords = vec3(mix(range_min,range_max,texture_coords), z);
  58     float n = noise3d(coords);
  59     return vec4(n,n,n,1.);
  60 }