code / tomo-game

   1 # This file defines a World object for keeping track of everything, as well
   2 # as the collision logic.
   3 use ./player.tm
   4 use ./raylib.tm
   5 use ./box.tm
   6 
   7 # Return a displacement relative to `a` that will push it out of `b`
   8 func solve_overlap(a_pos:Vector2, a_size:Vector2, b_pos:Vector2, b_size:Vector2 -> Vector2)
   9     a_left := a_pos.x
  10     a_right := a_pos.x + a_size.x
  11     a_top := a_pos.y
  12     a_bottom := a_pos.y + a_size.y
  13 
  14     b_left := b_pos.x
  15     b_right := b_pos.x + b_size.x
  16     b_top := b_pos.y
  17     b_bottom := b_pos.y + b_size.y
  18 
  19     # Calculate the overlap in each dimension
  20     overlap_x := (a_right _min_ b_right) - (a_left _max_ b_left)
  21     overlap_y := (a_bottom _min_ b_bottom) - (a_top _max_ b_top)
  22 
  23     # If either axis is not overlapping, then there is no collision:
  24     if overlap_x <= 0 or overlap_y <= 0
  25         return Vector2(0, 0)
  26 
  27     if overlap_x < overlap_y
  28         if a_right > b_left and a_right < b_right
  29             return Vector2(-(overlap_x), 0)
  30         else if a_left < b_right and a_left > b_left
  31             return Vector2(overlap_x, 0)
  32     else
  33         if a_top < b_bottom and a_top > b_top
  34             return Vector2(0, overlap_y)
  35         else if a_bottom > b_top and a_bottom < b_bottom
  36             return Vector2(0, -overlap_y)
  37 
  38     return Vector2(0, 0)
  39 
  40 struct World(player:@Player, goal:@Box, boxes:@[@Box], dt_accum=Num32(0.0), won=no)
  41     DT := (Num32(1.)/Num32(60.))
  42     STIFFNESS := Num32(0.3)
  43 
  44     func update(w:@World, dt:Num32)
  45         w.dt_accum += dt
  46         while w.dt_accum > 0
  47             w.update_once()
  48             w.dt_accum -= World.DT
  49 
  50     func update_once(w:@World)
  51         w.player.update()
  52 
  53         if solve_overlap(w.player.pos, Player.SIZE, w.goal.pos, w.goal.size) != Vector2(0,0)
  54             w.won = yes
  55 
  56         # Resolve player overlapping with any boxes:
  57         for i in 3
  58             for b in w.boxes
  59                 w.player.pos += World.STIFFNESS * solve_overlap(w.player.pos, Player.SIZE, b.pos, b.size)
  60 
  61     func draw(w:@World)
  62         for b in w.boxes
  63             b.draw()
  64         w.goal.draw()
  65         w.player.draw()
  66 
  67         if w.won
  68             DrawText(CString("WINNER"), GetScreenWidth()/Int32(2)-Int32(48*3), GetScreenHeight()/Int32(2)-Int32(24), 48, Color(0,0,0))
  69 
  70     func load_map(w:@World, map:Text)
  71         if map.has("[]")
  72             map = map.translate({"[]":"#", "@ ":"@", "  ":" "})
  73         w.boxes = @[]
  74         box_size := Vector2(50., 50.)
  75         for y,line in map.lines()
  76             for x,cell in line.split()
  77                 if cell == "#"
  78                     pos := Vector2((Num32(x)-1) * box_size.x, (Num32(y)-1) * box_size.y)
  79                     box := @Box(pos, size=box_size, color=Color(0x80,0x80,0x80))
  80                     w.boxes.insert(box)
  81                 else if cell == "@"
  82                     pos := Vector2((Num32(x)-1) * box_size.x, (Num32(y)-1) * box_size.y)
  83                     pos += box_size/Num32(2) - Player.SIZE/Num32(2)
  84                     w.player = @Player(pos,pos)
  85                 else if cell == "?"
  86                     pos := Vector2((Num32(x)-1) * box_size.x, (Num32(y)-1) * box_size.y)
  87                     w.goal.pos = pos
  88